/[svn]/ircd-hybrid-7.2/configure.ac
ViewVC logotype

Contents of /ircd-hybrid-7.2/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 978 - (show annotations)
Sun Aug 9 09:47:58 2009 UTC (11 years ago) by michael
File size: 7714 byte(s)
- avoid using native basename() since some implementations may or may not modify passed data

1 # Inspired by work Copyright (C) 2006 Luca Filipozzi
2 # vim: set fdm=marker ts=2 sw=2 et:
3
4 AC_REVISION([$Id$])
5
6 AC_PREREQ(2.63)
7 AC_INIT([ircd-hybrid], [7.2.4])
8 AM_INIT_AUTOMAKE(1.11)
9 AM_MAINTAINER_MODE
10 AC_CONFIG_HEADER(config.h)
11 AC_CONFIG_SRCDIR(src/ircd.c)
12
13
14 # Checks for programs.
15 AC_PROG_CC
16 AC_PROG_YACC
17 AM_PROG_LEX
18 AC_PROG_INSTALL
19
20
21 #ltdl stuff
22 LT_INIT([dlopen disable-static])
23 LTDL_INIT
24 LIBTOOL="$LIBTOOL --silent"
25
26
27 # Checks for libraries.
28 AX_CHECK_LIB_IPV4
29 AX_CHECK_LIB_IPV6
30
31
32 # Checks for typedefs, structures, and compiler characteristics.
33 AC_C_CONST
34 AC_C_INLINE
35 AC_C_BIGENDIAN
36
37 AC_CHECK_SIZEOF(int64_t)
38 AC_CHECK_SIZEOF(long long)
39
40 if test "$ac_cv_sizeof_int64_t" = 8; then
41 AC_CHECK_TYPE(uint64_t)
42 AC_CHECK_TYPE(int64_t)
43 elif test "$ac_cv_sizeof_long_long" = 8; then
44 AC_CHECK_TYPE(uint64_t, unsigned long long)
45 AC_CHECK_TYPE(int64_t, long long)
46 else
47 AC_MSG_ERROR([Your system doesn't appear to have 64 bit integers. Aborting.])
48 fi
49
50
51 # Checks for library functions.
52 AC_CHECK_FUNCS_ONCE(snprintf \
53 vsnprintf \
54 lrand48 \
55 srand48 \
56 mmap \
57 strtok_r \
58 usleep \
59 strlcat \
60 strlcpy)
61
62 # Checks for header files.
63 AC_CHECK_HEADERS_ONCE(crypt.h \
64 inttypes.h \
65 stdint.h \
66 sys/resource.h \
67 sys/param.h \
68 errno.h \
69 sys/syslog.h \
70 stddef.h \
71 libgen.h \
72 types.h \
73 socket.h \
74 sys/wait.h \
75 wait.h \
76 link.h)
77
78 dnl check for /dev/null so we can use it to hold evil fd's
79 AC_MSG_CHECKING([for /dev/null])
80 if test -c /dev/null ; then
81 AC_DEFINE(PATH_DEVNULL, "/dev/null", [Path to /dev/null])
82 AC_MSG_RESULT(yes)
83 else
84 AC_DEFINE(PATH_DEVNULL, "devnull.log", [Path to /dev/null])
85 AC_MSG_RESULT(no - using devnull.log)
86 fi
87
88
89 AC_SEARCH_LIBS(crypt, crypt)
90
91
92 AC_ARG_WITH(zlib-path,
93 AS_HELP_STRING([--with-zlib-path=DIR], [Path to libz.so for ziplinks support.]),
94 [LDFLAGS="-L$withval $LDFLAGS"],)
95
96 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib],[Disable ziplinks support]),
97 [zlib=$enableval],[zlib=yes])
98
99 if test "$zlib" = yes; then
100 AC_CHECK_HEADER(zlib.h, [AC_CHECK_LIB(z, zlibVersion,
101 [
102 LIBS="-lz $LIBS"
103 AC_DEFINE(HAVE_LIBZ, 1, [Define to 1 if zlib (-lz) is available.])
104 ], zlib=no)
105 ], zlib=no)
106 fi
107
108
109 dnl Openssl checks
110 AC_ARG_ENABLE(openssl,
111 [ --enable-openssl[=DIR] Enable OpenSSL support (DIR optional).
112 --disable-openssl Disable OpenSSL support. ],
113 [ cf_enable_openssl=$enableval ],
114 [ cf_enable_openssl="auto" ])
115 AC_MSG_CHECKING(for OpenSSL)
116 if test "$cf_enable_openssl" != "no"; then
117 cf_openssl_basedir=""
118 if test "$cf_enable_openssl" != "auto" &&
119 test "$cf_enable_openssl" != "yes"; then
120 dnl Support for --enable-openssl=/some/place
121 cf_openssl_basedir="${cf_enable_openssl}"
122 else
123 dnl Do the auto-probe here. Check some common directory paths.
124 for dirs in /usr/local/ssl /usr/pkg /usr/local /usr/lib /usr/lib/ssl\
125 /opt /opt/openssl /usr/local/openssl; do
126 if test -f "${dirs}/include/openssl/opensslv.h"; then
127 cf_openssl_basedir="${dirs}"
128 break
129 fi
130 done
131 unset dirs
132 fi
133
134 dnl Now check cf_openssl_found to see if we found anything.
135 if test ! -z "$cf_openssl_basedir"; then
136 if test -f "${cf_openssl_basedir}/include/openssl/opensslv.h"; then
137 CPPFLAGS="-I${cf_openssl_basedir}/include $CPPFLAGS"
138 LDFLAGS="-L${cf_openssl_basedir}/lib $LDFLAGS"
139 else
140 dnl OpenSSL wasn't found in the directory specified. Naughty
141 dnl administrator...
142 cf_openssl_basedir=""
143 fi
144 else
145 dnl Check for stock FreeBSD 4.x and 5.x systems, since their files
146 dnl are in /usr/include and /usr/lib. In this case, we don't want to
147 dnl change INCLUDES or LIBS, but still want to enable OpenSSL.
148 dnl We can't do this check above, because some people want two versions
149 dnl of OpenSSL installed (stock FreeBSD 4.x/5.x and /usr/local/ssl)
150 dnl and they want /usr/local/ssl to have preference.
151 if test -f "/usr/include/openssl/opensslv.h"; then
152 cf_openssl_basedir="/usr"
153 fi
154 fi
155
156 dnl If we have a basedir defined, then everything is okay. Otherwise,
157 dnl we have a problem.
158 if test ! -z "$cf_openssl_basedir"; then
159 LIBS="-lcrypto -lssl $LIBS"
160 AC_MSG_RESULT($cf_openssl_basedir)
161 cf_enable_openssl="yes"
162 AC_DEFINE(HAVE_LIBCRYPTO, 1, [If we support ssl])
163 else
164 AC_MSG_RESULT(not found. Please check your path.)
165 cf_enable_openssl="no"
166 fi
167 unset cf_openssl_basedir
168 else
169 dnl If --disable-openssl was specified
170 AC_MSG_RESULT(disabled)
171 fi
172 AM_CONDITIONAL(ENABLE_SSL, [test "$cf_enable_openssl" = yes])
173
174
175 AC_ARG_ENABLE(assert, AS_HELP_STRING([--enable-assert],
176 [Enable assert() statements]),
177 [assert=$enableval], [assert=no])
178 if test "$assert" = no; then
179 AC_DEFINE(NDEBUG, 1, [Define to disable assert() statements.])
180 fi
181
182
183 AC_ARG_ENABLE(small-net, AS_HELP_STRING([--enable-small-net],
184 [Enable small network support.]),
185 [small_net=$enableval], [small_net=no])
186
187 if test "$small_net" = yes; then
188 AC_DEFINE([NICKNAMEHISTORYLENGTH], 1500, [Size of the WHOWAS array.])
189 AC_DEFINE([CHANNEL_HEAP_SIZE], 256, [Size of the channel heap.])
190 AC_DEFINE([BAN_HEAP_SIZE], 128, [Size of the ban heap.])
191 AC_DEFINE([CLIENT_HEAP_SIZE], 256, [Size of the client heap.])
192 AC_DEFINE([LCLIENT_HEAP_SIZE], 128, [Size of the local client heap.])
193 AC_DEFINE([DNODE_HEAP_SIZE], 256, [Size of the dlink_node heap.])
194 AC_DEFINE([TOPIC_HEAP_SIZE], 256, [Size of the topic heap.])
195 AC_DEFINE([DBUF_HEAP_SIZE], 64, [Size of the dbuf heap.])
196 else
197 AC_DEFINE([NICKNAMEHISTORYLENGTH], 15000, [Size of the WHOWAS array.])
198 AC_DEFINE([CHANNEL_HEAP_SIZE], 1024, [Size of the channel heap.])
199 AC_DEFINE([BAN_HEAP_SIZE], 1024, [Size of the ban heap.])
200 AC_DEFINE([CLIENT_HEAP_SIZE], 1024, [Size of the client heap.])
201 AC_DEFINE([LCLIENT_HEAP_SIZE], 512, [Size of the local client heap.])
202 AC_DEFINE([DNODE_HEAP_SIZE], 1024, [Size of the dlink_node heap.])
203 AC_DEFINE([TOPIC_HEAP_SIZE], 1024, [Size of the topic heap.])
204 AC_DEFINE([DBUF_HEAP_SIZE], 512, [Size of the dbuf heap.])
205 fi
206
207
208 # Argument processing.
209 AX_ARG_ENABLE_IOLOOP_MECHANISM
210 AX_ARG_WITH_NICKLEN
211 AX_ARG_WITH_TOPICLEN
212 AX_ARG_WITH_SYSLOG
213 AX_ARG_ENABLE_EFNET
214 AX_ARG_ENABLE_HALFOPS
215 AX_ARG_ENABLE_DEBUGGING
216 AX_ARG_ENABLE_WARNINGS
217 AX_ARG_ENABLE_SYSLOG
218
219 AC_DEFINE_DIR([PREFIX],[prefix],[Set to prefix.])
220 AC_DEFINE_DIR([SYSCONFDIR],[sysconfdir],[Set to sysconfdir.])
221 AC_DEFINE_DIR([LIBDIR],[libdir],[Set to libdir.])
222 AC_DEFINE_DIR([DATADIR],[datadir],[Set to datadir.])
223 AC_DEFINE_DIR([LOCALSTATEDIR],[localstatedir],[Set to localstatedir.])
224
225 AC_CONFIG_FILES( \
226 Makefile \
227 etc/Makefile \
228 etc/example.conf \
229 etc/example.conf.quick \
230 etc/example.efnet.conf \
231 servlink/Makefile \
232 contrib/Makefile \
233 contrib/help/Makefile \
234 src/Makefile \
235 messages/Makefile \
236 modules/Makefile \
237 modules/core/Makefile \
238 doc/Makefile \
239 help/Makefile \
240 help/opers/Makefile \
241 help/users/Makefile \
242 lib/Makefile \
243 lib/pcre/Makefile \
244 tools/Makefile
245 )
246
247 AC_OUTPUT

Properties

Name Value
svn:eol-style native
svn:keywords Id Revision

svnadmin@ircd-hybrid.org
ViewVC Help
Powered by ViewVC 1.1.28